En Desinstalar Avira Launcher, os explicaba como eliminar definitivamente de nuestras instalaciones de Avira Antivirus (antes Avira Antivir).

En mi comentario, os actualizaba que el sistema propuesto había dejado de funcionar, pues las actualizaciones de Avira, reinstalarían Avira Launcher si detectaba que éste no estaba instalado.

Desilusionado como tantos otros usuarios, al ver como ese “troyano”, se reinstalaba en nuestro equipo sin dar consentimiento alguno, decidí volver a Avast, y ahorrarme quebraderos de cabeza. Soy incapaz de comprender como siendo Avira, uno de los antivirus más ligeros del mercado, han optado por crear Launcher, escrito en .NET, que consume más recursos que el propio antivirus, sin proporcionar nada de utilidad al respecto.

Imaginaba que la reinstalación automática de Launcher, podría evitarse jugando con los permisos de NTFS, pero antes de llegarlo a probar, uVe compartió la solución de su amigo Iván. Desinstalar Avira Launcher quedaba solucionado, porque ese sistema funcionaba correctamente.

En realidad no lo desinstalaba, sino que lo desactivaba, pero a efectos prácticos es lo mismo, con la salvedad que tendremos 10 Mb. de espacio en disco ocupado en C:\Program Files (x86)\Avira\Launcher, y que nunca utilizaremos.

El método era elegante por su simplicidad. Consistía en anular los ejecutables clave de Launcher (Avira.ServiceHost.exe y Avira.SystrayStartTrigger.exe), anulándolos con el inocuo Avira.Messenger.exe.

Usando su procedimiento, me di cuenta que los desarrolladores de Avira, seguramente inyectarían una nueva versión de Avira Launcher que desactivaría el “arreglo”. Y sugería la opción de crear un simple archivo BAT, que fuera ejecutarlo, y efectuar todo el proceso de manera automática.

Dicho y hecho, en 10 minutos tenía algo como esto:

@echo off
echo.
echo Desactivar Avira Launcher 1.03 - //www.javiergutierrezchamorro.com - 31/10/2016
echo.
 
echo Comprobando permisos de administrador...
net session > nul 2>&1
if %errorLevel% neq 0 goto NoAdmin
 
echo Parando servicio Avira.ServiceHost.exe...
net stop "Avira Service Host" > nul
 
echo Desactivando servicio Avira.ServiceHost.exe...
sc config "Avira.ServiceHost" start=disabled > nul
 
echo Detectando Avira Launcher...
if ["%ProgramFiles(x86)%"] neq [] goto Pathx86
set PathLauncher=%ProgramFiles%\Avira\Launcher
goto Continue
 
:Pathx86
set PathLauncher=%ProgramFiles(x86)%\Avira\Launcher
 
:Continue
echo Detectado Avira Launcher en %PathLauncher%...
 
echo Cerrando Avira.Systray.exe...
taskkill /im Avira.Systray.exe > nul
 
echo Deshabilitando Avira.ServiceHost.exe...
del "%PathLauncher%\Avira.ServiceHost.exe.bak" > nul
ren "%PathLauncher%\Avira.ServiceHost.exe" "Avira.ServiceHost.exe.bak" > nul
copy "%PathLauncher%\Avira.Messenger.exe" "%PathLauncher%\Avira.ServiceHost.exe"  > nul
 
 
echo Deshabilitando Avira.SystrayStartTrigger.exe...
del "%PathLauncher%\Avira.SystrayStartTrigger.exe.bak" > nul
ren "%PathLauncher%\Avira.SystrayStartTrigger.exe" "Avira.SystrayStartTrigger.exe.bak" > nul
copy "%PathLauncher%\Avira.Messenger.exe" "%PathLauncher%\Avira.SystrayStartTrigger.exe" > nul
 
echo.
echo ¡Avira Launcher ha sido desactivado correctamente!
pause > nul
 
goto End
 
:NoAdmin
echo Error. Debes ejecutar este archivo con permisos de administrador
pause > nul
 
:End

Si lo quieres descargar directamente lo tienes aquí (1 Kb. en formato BAT). No olvides que debe ejecutarse como administrador.